Social Security Contributions and Benefits Act 1992 Work packageable things

1992 c. 4. An Act of Parliament gaining Royal Assent on 13 February 1992.

Read the enabling legislation at legislation.gov.uk.

Instruments listed here are those laid since the start of the 2017-19 session, subject to parliamentary procedure.

There are 197 work packageable things.

Showing 151 - 197 of 197.

Previous Next

Enabling legislation identifier

https://id.parliament.uk/6H5k5vC4

SPARQL queries used by this page

An enabling legislation

Count of all work packageable things for enabling legislation with ID 6H5k5vC4

# We declare the Parliament and ID namespaces.    
PREFIX : <https://id.parliament.uk/schema/>
PREFIX id: <https://id.parliament.uk/>

# We select the properties we want to appear in results.
# If all properties are required, an asterisk can be used between SELECT and WHERE instead of listing properties.
# We count the number of distinct work packageable things for an item of enabling legislation.
SELECT (COUNT(DISTINCT ?workPackagedThing) AS ?count) WHERE {

# We find all enabling legislation and their names.   
  ?act a :ActOfParliament;
  :actOfParliamentName ?name.

# We specify that the enabling legislation may, or may not, have a number, year, royal assent date and URL.
  OPTIONAL {
    ?act :actOfParliamentNumber ?number
  }
  OPTIONAL {
    ?act :actOfParliamentYear ?year
  }
  OPTIONAL{ 
   ?act :actOfParliamentRoyalAssentDate ?date
  }
  OPTIONAL {
    ?act :actOfParliamentUrl ?url
  }
  
  # We filter the results to only include enabling legislation with ID 6H5k5vC4.
  FILTER ( ?act IN ( id:6H5k5vC4 ) )

# We find all work packaged things of the enabling legislation and their names.
  ?act :enabling ?workPackagedThing. 
  ?workPackagedThing :name ?workPackagedThingName. 
  }

Work packageable things for enabling legislation with ID 6H5k5vC4

# We declare the Parliament and ID namespaces.    
PREFIX : <https://id.parliament.uk/schema/>
PREFIX id: <https://id.parliament.uk/>
      
# We select the properties we want to appear in results.
# If all properties are required, an asterisk can be used between SELECT and WHERE instead of listing properties.
SELECT ?workPackagedThing ?workPackagedThingName ?businessItemDate ?procedure ?procedureName WHERE {

# We find all enabling legislation and their names.  
  ?act a :ActOfParliament.
  ?act :actOfParliamentName ?name.

# We specify that the enabling legislation may, or may not, have a number, year, royal assent date and URL. 
  OPTIONAL {
    ?act :actOfParliamentNumber ?number
  }

OPTIONAL {
    ?act :actOfParliamentYear ?year
  }

OPTIONAL{ 
   ?act :actOfParliamentRoyalAssentDate ?date
  }
  OPTIONAL {
    ?act :actOfParliamentUrl ?url
  }
  
  # We filter the results to only include enabling legislation with ID 6H5k5vC4.
  FILTER ( ?act IN ( id:6H5k5vC4 ) )
  
  # We find all work packaged things of the enabling legislation and their names, and the work packages of the work packaged things.
  ?act :enabling ?workPackagedThing. 
  ?workPackagedThing :name ?workPackagedThingName;
  :workPackagedThingHasWorkPackage ?workPackage.
  
  # We find the making available business item, if there is one, of the work packages and it's date.
  OPTIONAL {
    ?workPackage :workPackageHasBusinessItem ?businessItem .
    ?businessItem :businessItemHasProcedureStep ?step;
    :businessItemDate ?businessItemDate.
    FILTER ( ?step IN ( id:isWn7s3K, id:cspzmb6w, id:ITNO9JWr, id:otscOTzB ) )
  }
  
  # We find the procedure of the work packages and the procedure names.
  ?workPackage :workPackageHasProcedure ?procedure.
  ?procedure :name ?procedureName.
                     
} 
# We order the results by business item date in descending order.  
ORDER BY DESC(?businessItemDate)          
# We limit the number of results returned and we offset the results returned by a specified number.          
LIMIT 50 OFFSET 150