Made negative SUM

1 January 1948 -

Instruments subject to the made negative procedure do not require approval in Parliament before becoming law. These instruments may come into force on any date after being laid. Instruments concerning taxation are not laid in the Lords. Either House may pass a motion within the objection period which annuls the instrument and stops it having effect.

There are 35 steps.

Download CSV

Step	Actualisation count
AE SUM	0
AT SUM	0
EVEL CERT AA SUM	0
EVEL CERT AB SUM	0
EVEL CERT AC SUM	0
JCSI AA SUM	0
NCM AA SUM	0
NCM AB SUM	0
NCM AC SUM	0
NCM AE SUM	0
NCM AJ SUM	0
NCM AK SUM	0
NCM AL SUM	0
NCMC AA SUM	0
NCMC AB SUM	0
NCMC AC SUM	0
NCMC AE SUM	0
NLM AA SUM	0
NLM AB SUM	0
NLM AC SUM	0
NLM AE SUM	0
NLM AJ SUM	0
NLM AK SUM	0
NLM AL SUM	0
NLM AN SUM	0
NLM AO SUM	0
NLM AP SUM	0
NLM AR SUM	0
RDLC AA SUM	0
RDLC AB SUM	0
RDLC AC SUM	0
RDLC AE SUM	0
SCSI AA SUM	0
SLSC AA SUM	0
SLSC AB SUM	0

Procedure identifier

https://id.parliament.uk/5S6p4YsP

SPARQL queries used by this page

A list of steps of a type within a procedure

# We declare the Parliament and ID namespaces.
PREFIX : <https://id.parliament.uk/schema/>
PREFIX id: <https://id.parliament.uk/>

# We select the properties we want to appear in results. If all properties are required, an asterisk can be used between SELECT and WHERE instead of listing properties.
SELECT DISTINCT ?procedure ?procedureName ?stepType ?stepTypeLabel ?step ?stepName ?legislature ?legislatureName ?commonsId ?lordsId (COALESCE(?rawBiCount, 0) AS ?biCount) WHERE {

# We set the value of the procedure property.   
VALUES ?procedure { id:5S6p4YsP }

# We specify that the procedure property is a procedure and look for its name.   
?procedure a :Procedure;
:name ?procedureName.

# We look for all procedure routes and the steps in those routes, including whether they are a From step or a To step. The pipe in line 17 is a SPARQL OR.  
?procedure :procedureHasProcedureRoute ?route.
?route :procedureRouteIsFromProcedureStep|:procedureRouteIsToProcedureStep ?step.

# We specify the procedure step must have a name, a step type and that the step type also has a name.   
?step :name ?stepName.
?step :procedureStepHasProcedureStepType ?stepType.
?stepType :name ?stepTypeLabel.

# We limit steps to being only of the type 'Business step'.
FILTER (?stepType in (id:SFKy7wHE))

# We check to see if the step belongs to a legislature. A legislature will be Scottish Parliament, Senedd Cymru or the Northern Ireland Assembly.   
OPTIONAL {?step :procedureStepInLegislature ?legislature .
?legislature :name ?legislatureName .}

# We check to see if the step belongs to the House of Commons.     
OPTIONAL {?step :procedureStepHasHouse ?commonsId .
FILTER (?commonsId = id:1AFu55Hs)}

# We check to see if the step belongs to the House of Lords.   
OPTIONAL {?step :procedureStepHasHouse ?lordsId .
FILTER (?lordsId = id:WkUWUBMx)}

# We specify an optional subquery which calculates the number of distinct business items that actualise a steps from the procedure. We make it optional because not every step will be actualised in a business item.   
OPTIONAL {
SELECT ?step (COUNT(DISTINCT ?bi) AS ?rawBiCount)
WHERE {
# We find business items actualising the step. 
?step :procedureStepHasBusinessItem ?bi .

# We find the work package each business item belongs to.
?bi :businessItemHasWorkPackage ?wp.

# We specify that the work packages must have the procedure. 
?wp :workPackageHasProcedure id:5S6p4YsP.}

# We group the results by step.    
GROUP BY ?step}
}

# We order the results by step name. 
ORDER BY ?stepName