Legislative Consent Motion - Scottish Parliament Business step

There are 47 steps.

Step	Actualisation count
Bill provides relevant delegated powers (Scottish Parliament)	0
Call for evidence by the lead committee (Scottish Parliament)	0
Considered by the Delegated Powers and Law Reform Committee (Scottish Parliament)	0
Considered by the lead committee (Scottish Parliament)	0
Debate on legislative consent motion (Scottish Parliament)	0
Debate on motion to suspend standing orders in relation to legislative consent motions (Scottish Parliament)	0
Fatal amendment to legislative consent motion agreed to (Scottish Parliament)	0
Fatal amendment to legislative consent motion falls at dissolution (Scottish Parliament)	0
Fatal amendment to legislative consent motion lodged (Scottish Parliament)	0
Fatal amendment to legislative consent motion not agreed to (Scottish Parliament)	0
Fatal amendment to legislative consent motion not called (Scottish Parliament)	0
Fatal amendment to legislative consent motion not moved (Scottish Parliament)	0
Fatal amendment to legislative consent motion not selected by the Presiding Officer (Scottish Parliament)	0
Fatal amendment to legislative consent motion withdrawn (Scottish Parliament)	0
Lead committee does not support the granting of consent (Scottish Parliament)	0
Lead committee does not take a position on the granting of consent (Scottish Parliament)	0
Lead committee supports the granting of consent (Scottish Parliament)	0
Legislative consent granted (Scottish Parliament)	0
Legislative consent memorandum lodged by a Member including a draft legislative consent motion (Scottish Parliament)	0
Legislative consent memorandum lodged by the Scottish Government (Scottish Parliament)	0
Legislative consent motion falls at dissolution (Scottish Parliament)	0
Legislative consent motion lodged (Scottish Parliament)	0
Legislative consent motion not called (Scottish Parliament)	0
Legislative consent motion not moved (Scottish Parliament)	0
Legislative consent motion withdrawn (Scottish Parliament)	0
Legislative consent not granted (Scottish Parliament)	0
Motion to suspend standing orders in relation to legislative consent motions agreed to (Scottish Parliament)	0
Motion to suspend standing orders in relation to legislative consent motions falls at dissolution (Scottish Parliament)	0
Motion to suspend standing orders in relation to legislative consent motions not agreed to (Scottish Parliament)	0
Motion to suspend standing orders in relation to legislative consent motions tabled (Scottish Parliament)	0
Motion to suspend standing orders in relation to legislative consent motions withdrawn (Scottish Parliament)	0
Non-fatal amendment to legislative consent motion agreed to (Scottish Parliament)	0
Non-fatal amendment to legislative consent motion falls at dissolution (Scottish Parliament)	0
Non-fatal amendment to legislative consent motion lodged (Scottish Parliament)	0
Non-fatal amendment to legislative consent motion not agreed to (Scottish Parliament)	0
Non-fatal amendment to legislative consent motion not called (Scottish Parliament)	0
Non-fatal amendment to legislative consent motion not moved (Scottish Parliament)	0
Non-fatal amendment to legislative consent motion not selected by the Presiding Officer (Scottish Parliament)	0
Non-fatal amendment to legislative consent motion withdrawn (Scottish Parliament)	0
Oral evidence session by the lead committee (Scottish Parliament)	0
Question put on fatal amendment to legislative consent motion (Scottish Parliament)	0
Question put on legislative consent motion (Scottish Parliament)	0
Question put on motion to suspend standing orders in relation to legislative consent motions (Scottish Parliament)	0
Question put on non-fatal amendment to legislative consent motion (Scottish Parliament)	0
Referred to a lead committee by the Parliamentary Bureau (Scottish Parliament)	0
Scottish Government does not intend to lodge a legislative consent motion (Scottish Parliament)	0
Scottish Government intends to lodge a legislative consent motion (Scottish Parliament)	0

Procedure identifier

https://id.parliament.uk/6J4vIkHl

SPARQL queries used by this page

A list of steps of a type within a procedure

# We declare the Parliament and ID namespaces.
PREFIX : <https://id.parliament.uk/schema/>
PREFIX id: <https://id.parliament.uk/>

# We select the properties we want to appear in results. If all properties are required, an asterisk can be used between SELECT and WHERE instead of listing properties.
SELECT DISTINCT ?procedure ?procedureName ?stepType ?stepTypeLabel ?step ?stepName ?legislature ?legislatureName ?commonsId ?lordsId (COALESCE(?rawBiCount, 0) AS ?biCount) WHERE {

# We set the value of the procedure property.   
VALUES ?procedure { id:6J4vIkHl }

# We specify that the procedure property is a procedure and look for its name.   
?procedure a :Procedure;
:name ?procedureName.

# We look for all procedure routes and the steps in those routes, including whether they are a From step or a To step. The pipe in line 17 is a SPARQL OR.  
?procedure :procedureHasProcedureRoute ?route.
?route :procedureRouteIsFromProcedureStep|:procedureRouteIsToProcedureStep ?step.

# We specify the procedure step must have a name, a step type and that the step type also has a name.   
?step :name ?stepName.
?step :procedureStepHasProcedureStepType ?stepType.
?stepType :name ?stepTypeLabel.

# We limit steps to being only of the type 'Business step'.
FILTER (?stepType in (id:Jwc6nqJi))

# We check to see if the step belongs to a legislature. A legislature will be Scottish Parliament, Senedd Cymru or the Northern Ireland Assembly.   
OPTIONAL {?step :procedureStepInLegislature ?legislature .
?legislature :name ?legislatureName .}

# We check to see if the step belongs to the House of Commons.     
OPTIONAL {?step :procedureStepHasHouse ?commonsId .
FILTER (?commonsId = id:1AFu55Hs)}

# We check to see if the step belongs to the House of Lords.   
OPTIONAL {?step :procedureStepHasHouse ?lordsId .
FILTER (?lordsId = id:WkUWUBMx)}

# We specify an optional subquery which calculates the number of distinct business items that actualise a steps from the procedure. We make it optional because not every step will be actualised in a business item.   
OPTIONAL {
SELECT ?step (COUNT(DISTINCT ?bi) AS ?rawBiCount)
WHERE {
# We find business items actualising the step. 
?step :procedureStepHasBusinessItem ?bi .

# We find the work package each business item belongs to.
?bi :businessItemHasWorkPackage ?wp.

# We specify that the work packages must have the procedure. 
?wp :workPackageHasProcedure id:6J4vIkHl.}

# We group the results by step.    
GROUP BY ?step}
}

# We order the results by step name. 
ORDER BY ?stepName