Treaties subject to the Constitutional Reform and Governance Act 2010 SUM

11 November 2010 -

A treaty may be ratified if the Commons does not resolve against ratification within 21 sitting days. A Minister may extend this period. If the Commons resolves against ratification, a Minister may make a statement in disagreement, following which the Commons may consider for a further 21 sitting days. Even if the Lords resolves against ratification, a Minister may make a statement that the treaty be ratified. A Minister may determine a treaty be ratified without it being laid before Parliament.

There are 38 steps.

Download CSV

Step	Actualisation count
AK SUM	0
BE SUM	0
CTCM AA SUM	0
CTCM AB SUM	0
CTCM AC SUM	0
CTCM AD SUM	0
CTCM AE SUM	0
CTCM AF SUM	0
CTCM AG SUM	0
CTCM AH SUM	0
CTCM AI SUM	0
CTCM AJ SUM	0
CTCM AK SUM	0
CTLM AA SUM	0
CTLM AB SUM	0
CTLM AC SUM	0
CTLM AD SUM	0
CTLM AE SUM	0
CTLM AF SUM	0
CTLM AG SUM	0
CTLM AH SUM	0
CTLM AI SUM	0
CTLM AJ SUM	0
CTLM AK SUM	0
CTLM AL SUM	0
CTLM AM SUM	0
CTLM AN SUM	0
CTLM AO SUM	0
TREATY BAT AA SUM	0
TREATY IAC+EAC AA SUM	0
TREATY IAC+EAC AB SUM	0
TREATY IAC+EAC AC SUM	0
TREATY IAC+EAC AD SUM	0
TREATY ITC AA SUM	0
TREATY JCHR AA SUM	0
TREATY LORDS AA SUM	0
TREATY LORDS AB SUM	0
TREATY LORDS AC SUM	0

Procedure identifier

https://id.parliament.uk/D00dsjR2

SPARQL queries used by this page

A list of steps of a type within a procedure

# We declare the Parliament and ID namespaces.
PREFIX : <https://id.parliament.uk/schema/>
PREFIX id: <https://id.parliament.uk/>

# We select the properties we want to appear in results. If all properties are required, an asterisk can be used between SELECT and WHERE instead of listing properties.
SELECT DISTINCT ?procedure ?procedureName ?stepType ?stepTypeLabel ?step ?stepName ?legislature ?legislatureName ?commonsId ?lordsId (COALESCE(?rawBiCount, 0) AS ?biCount) WHERE {

# We set the value of the procedure property.   
VALUES ?procedure { id:D00dsjR2 }

# We specify that the procedure property is a procedure and look for its name.   
?procedure a :Procedure;
:name ?procedureName.

# We look for all procedure routes and the steps in those routes, including whether they are a From step or a To step. The pipe in line 17 is a SPARQL OR.  
?procedure :procedureHasProcedureRoute ?route.
?route :procedureRouteIsFromProcedureStep|:procedureRouteIsToProcedureStep ?step.

# We specify the procedure step must have a name, a step type and that the step type also has a name.   
?step :name ?stepName.
?step :procedureStepHasProcedureStepType ?stepType.
?stepType :name ?stepTypeLabel.

# We limit steps to being only of the type 'Business step'.
FILTER (?stepType in (id:SFKy7wHE))

# We check to see if the step belongs to a legislature. A legislature will be Scottish Parliament, Senedd Cymru or the Northern Ireland Assembly.   
OPTIONAL {?step :procedureStepInLegislature ?legislature .
?legislature :name ?legislatureName .}

# We check to see if the step belongs to the House of Commons.     
OPTIONAL {?step :procedureStepHasHouse ?commonsId .
FILTER (?commonsId = id:1AFu55Hs)}

# We check to see if the step belongs to the House of Lords.   
OPTIONAL {?step :procedureStepHasHouse ?lordsId .
FILTER (?lordsId = id:WkUWUBMx)}

# We specify an optional subquery which calculates the number of distinct business items that actualise a steps from the procedure. We make it optional because not every step will be actualised in a business item.   
OPTIONAL {
SELECT ?step (COUNT(DISTINCT ?bi) AS ?rawBiCount)
WHERE {
# We find business items actualising the step. 
?step :procedureStepHasBusinessItem ?bi .

# We find the work package each business item belongs to.
?bi :businessItemHasWorkPackage ?wp.

# We specify that the work packages must have the procedure. 
?wp :workPackageHasProcedure id:D00dsjR2.}

# We group the results by step.    
GROUP BY ?step}
}

# We order the results by step name. 
ORDER BY ?stepName