Made affirmative remedial order OR

2 October 2000 -

A remedial order is an order made by a minister under the Human Rights Act 1998 to amend legislation which has been found incompatible with the European Convention on Human Rights. Remedial orders can be used to amend both primary and secondary legislation, and they may do anything necessary to fix the incompatibility with the Convention rights. Urgent orders may be made without advance scrutiny, but they will stop being law if they are not approved by both Houses within 120 days of being laid before Parliament.

There are 28 steps.

Download CSV

Step	Actualisation count
AC OR	0
ACM AC OR	0
ACM AD OR	0
AD OR	0
AE OR	0
AF OR	0
AH OR	0
AI OR	0
AJ OR	0
AK OR	0
AN OR	0
AO OR	0
AP OR	0
AQ OR	0
AR OR	0
AS OR	0
AT OR	0
AU OR	0
AV OR	0
AW OR	0
AX OR	0
AY OR	0
JCHRSR AA OR	0
JCHRSR AB OR	0
MALM AA OR	0
MALM AB OR	0
MALM AC OR	0
MALM AD OR	0

Procedure identifier

https://id.parliament.uk/iAISgq1R

SPARQL queries used by this page

A list of steps of a type within a procedure

# We declare the Parliament and ID namespaces.
PREFIX : <https://id.parliament.uk/schema/>
PREFIX id: <https://id.parliament.uk/>

# We select the properties we want to appear in results. If all properties are required, an asterisk can be used between SELECT and WHERE instead of listing properties.
SELECT DISTINCT ?procedure ?procedureName ?stepType ?stepTypeLabel ?step ?stepName ?legislature ?legislatureName ?commonsId ?lordsId (COALESCE(?rawBiCount, 0) AS ?biCount) WHERE {

# We set the value of the procedure property.   
VALUES ?procedure { id:iAISgq1R }

# We specify that the procedure property is a procedure and look for its name.   
?procedure a :Procedure;
:name ?procedureName.

# We look for all procedure routes and the steps in those routes, including whether they are a From step or a To step. The pipe in line 17 is a SPARQL OR.  
?procedure :procedureHasProcedureRoute ?route.
?route :procedureRouteIsFromProcedureStep|:procedureRouteIsToProcedureStep ?step.

# We specify the procedure step must have a name, a step type and that the step type also has a name.   
?step :name ?stepName.
?step :procedureStepHasProcedureStepType ?stepType.
?stepType :name ?stepTypeLabel.

# We limit steps to being only of the type 'Business step'.
FILTER (?stepType in (id:NouCqeQQ))

# We check to see if the step belongs to a legislature. A legislature will be Scottish Parliament, Senedd Cymru or the Northern Ireland Assembly.   
OPTIONAL {?step :procedureStepInLegislature ?legislature .
?legislature :name ?legislatureName .}

# We check to see if the step belongs to the House of Commons.     
OPTIONAL {?step :procedureStepHasHouse ?commonsId .
FILTER (?commonsId = id:1AFu55Hs)}

# We check to see if the step belongs to the House of Lords.   
OPTIONAL {?step :procedureStepHasHouse ?lordsId .
FILTER (?lordsId = id:WkUWUBMx)}

# We specify an optional subquery which calculates the number of distinct business items that actualise a steps from the procedure. We make it optional because not every step will be actualised in a business item.   
OPTIONAL {
SELECT ?step (COUNT(DISTINCT ?bi) AS ?rawBiCount)
WHERE {
# We find business items actualising the step. 
?step :procedureStepHasBusinessItem ?bi .

# We find the work package each business item belongs to.
?bi :businessItemHasWorkPackage ?wp.

# We specify that the work packages must have the procedure. 
?wp :workPackageHasProcedure id:iAISgq1R.}

# We group the results by step.    
GROUP BY ?step}
}

# We order the results by step name. 
ORDER BY ?stepName